home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Cream of the Crop 22
/
Cream of the Crop 22.iso
/
utility
/
tsbat50.zip
/
SAMENAME.BAT
< prev
next >
Wrap
DOS Batch File
|
1996-08-24
|
2KB
|
56 lines
@echo off
echo.
echo ┌───────────────────────────────────────────────────┐
echo │ Find the files with the same name on a drive │
echo │ Copyright by Prof. Timo Salmi Sat 24-Aug-96 │
echo │ Email: ts@uwasa.fi WWW: http://www.uwasa.fi/~ts/ │
echo └───────────────────────────────────────────────────┘
echo.
set drive_=%1
set auxdr_=R:
if "%drive_%"=="" goto _usage
rem Auxiliary drive
if not exist %auxdr_%\nul goto _err1
rem The drive to be scanned for size duplicates
if not exist %drive_%\nul goto _err2
rem The "engine"
dir %drive_%\ /s | find /V "<DIR>" > %auxdr_%samenam1.$$$
find /V "Directory of" < %auxdr_%samenam1.$$$ > %auxdr_%samenam2.$$$
find /V "Total files listed:" < %auxdr_%samenam2.$$$ > %auxdr_%samenam1.$$$
find /V " file(s)" < %auxdr_%samenam1.$$$ > %auxdr_%samenam2.$$$
find /V " bytes free" < %auxdr_%samenam2.$$$ > %auxdr_%samenam1.$$$
find /V "Volume in drive" < %auxdr_%samenam1.$$$ > %auxdr_%samenam2.$$$
find /V "Volume Serial Number is" < %auxdr_%samenam2.$$$ > %auxdr_%samenam1.$$$
find ":" < %auxdr_%samenam1.$$$ > %auxdr_%samenam2.$$$
sort < %auxdr_%samenam2.$$$ > %auxdr_%samenam1.$$$
rem Present the results
type %auxdr_%samenam1.$$$
copy %auxdr_%samenam1.$$$ %auxdr_%samename.rpt > nul
echo.
echo The results are stored in %auxdr_%samename.rpt
rem Delete the auxiliary files
if exist %auxdr_%samenam1.$$$ del %auxdr_%samenam1.$$$
if exist %auxdr_%samenam2.$$$ del %auxdr_%samenam2.$$$
goto _end
:_err1
echo Auxiliary drive %auxdr_% not found
echo Reconfigure the batch variable auxdr_ to point to a valid drive on your system
goto _end
:_err2
echo Invalid drive %drive_%
:_usage
echo Usage %0 Drive:
:_end
set drive_=
set auxdr_=